Two formulas were missing in the InSynch system you posted (they're also missing in the original note with the WOW formulas). The formulas are:
STO%dInS
If( Stoch(14 ,3 )> 80 ,5 ,If( Stoch(14 ,3 )<20 ,-5 ,0 ) )
STO%kInS
If( Stoch(14 ,1)> 80 ,5 ,If( Stoch(14 ,1 )<20 ,-5 ,0 ) )
So now the whole translation of the InSync formula for WOW is:
BOLInSLB
mov(C,20,S) - 2 * (std(C ,20))
BOLInSUB
mov(C,20,S) + 2 * (std(C , 20))
BOLInS2
(C-fml("BOLInSLB")) / (fml("BOLInSUB") - fml("BOLInSLB"))
BOLInSLL
if(fml("BOLInS2") < .05, -5, if(fml("BOLInS2") > .95, 5, 0))
CCIInS
if(cci(14) > 100, 5, if(cci(14)< -100, -5, 0))
EMVInS2
emv(10,S,1) - mov(emv(10,S,1),10,S)
EMVInSB
if(fml("EMVInS2")< 0, if(mov(emv(10,S,1),10,S) < 0, -5, 0),0)
EMVInSS
if(fml("EMVInS2")> 0,if(mov(emv(10,S,1),10,S) > 0, 5, 0),0)
MACDInS2
macd() - mov(macd(), 10, S)
MACDInSB
if(fml("MACDInS2") < 0, if(mov(macd(),10,S) < 0, -5, 0), 0)
MACDInSS
if(fml("MACDInS2") > 0, if(mov(macd(),10, S)> 0, 5, 0), 0)
MFIIns
if(mfi(20)> 80,5,if(mfi(20)< 20,-5,0))
PDOInS2
dpo(18) - mov(dpo(18), 10, S)
PDOInSB
if(fml("PDOInS2")< 0, if(mov(dpo(18),10,S) < 0, -5, 0), 0)
PDOInSS
if(fml("PDOInS2") > 0, if(mov(dpo(18),10,S) > 0, 5, 0), 0)
ROCInS2
roc(C , 10, $) - mov(roc(C,10,$), 10,S)
ROCInSB
if(fml("ROCInS2") < 0, if(mov(roc(C,10,$),10,S)< 0,-5,0),0)
ROCInSS
if(fml("ROCInS2")> 0, if(mov(roc(C,10,$), 10,S)> 0,5,0),0)
RSIInS
if(rsi(14)> 70,5,if(rsi(14)< 30,-5,0))
STO%dInS
If( Stoch(14 ,3 )> 80 ,5 ,If( Stoch(14 ,3 )<20 ,-5 ,0 ) )
STO%kInS
If( Stoch(14 ,1)> 80 ,5 ,If( Stoch(14 ,1 )<20 ,-5 ,0 ) )
Insynch Indicator
50 + fml("CCIInS") + fml("BOLInSLL") + fml("RSIInS") + fml("sto%kInS") + fml("sto%dInS") +
fml("MFIInS") + fml("EMVInSB") + fml("EMVInSS") + fml("ROCInSS") + fml("ROCInSB") +
ref(fml("PDOInSS"),-10) + ref(fml("PDOInSB"),-10) + fml("MACDInSS") + fml("MACDInSB")
I can hear Bill Riedeman chuckling as he reads this one. No, Bill, this isn't a joke. And no, I don't pretend to understand it. And yes, I'm up to my old trick -- using formulas I don't understand. Mea culpa. Twenty lashings. One hundred pardons. |
