Here's an effort to formulate Dave's Newest New System, based on what he said in his presentation. I don't mean to flood you with all these systems -- you don't have to examine them. But I thought you (or others) might be interested. This is a long one, but basically, it's just looking for two versions of StochRSI to be over 30, MACD(8,17,9) to be over 0, InSync to be over 50, Dahl over 0 and price on top of Parabolic SAR. The longest part of the formula concerns InSync, which must be created in WOW before you can use it. Creating InSync takes a while, but all the elements are included here.
fml("StochRSI")>30 and
fml("StocRSI(8,5)")>30 and
fml("MACD (8/17/9)")>0 and
fml("InSync Indicator")>50 and
fml ("Dahl's primary trend")>0 and
SAR(.02,.2)<C
Exit short term:
fml("MACD (8/17/9)")<0 and
fml("StochRSI")<70 and
SAR(.02,.2)>C
Exit long term:
fml("DNS")<3 and
fml("Dahl's primary trend")<0
The system is made of of all this junk:
StochRSI: Mov((RSI(14)- LLV(RSI(14),14)) /(HHV(RSI(14),14)-(LLV(RSI(14),14))),14,E)*100
StocRSI(8,5): Mov((RSI(8)-LLV(RSI(8),8))/(HHV(RSI(8),8)-(LLV(RSI(8),8))),5,w)*100
MACD (8/17/9)
1. mov(c,8,e) - mov(c,17,e)
2. mov((mov(c,8,e) - mov(c,17,e)),9,e)
InSync Indicator (everything below, I'm sorry to say, must be created in WOW one at a time):
BOLInSLB
mov(C,20,S) - 2 * (std(C ,20))
BOLInSUB
mov(C,20,S) + 2 * (std(C , 20))
BOLInS2
(C-fml("BOLInSLB")) / (fml("BOLInSUB") - fml("BOLInSLB"))
BOLInSLL
if(fml("BOLInS2") < .05, -5, if(fml("BOLInS2") > .95, 5, 0))
CCIInS
if(cci(14) > 100, 5, if(cci(14)< -100, -5, 0))
EMVInS2
emv(10,S,1) - mov(emv(10,S,1),10,S)
EMVInSB
if(fml("EMVInS2")< 0, if(mov(emv(10,S,1),10,S) < 0, -5, 0),0)
EMVInSS
if(fml("EMVInS2")> 0,if(mov(emv(10,S,1),10,S) > 0, 5, 0),0)
MACDInS2
macd() - mov(macd(), 10, S)
MACDInSB
if(fml("MACDInS2") < 0, if(mov(macd(),10,S) < 0, -5, 0), 0)
MACDInSS
if(fml("MACDInS2") > 0, if(mov(macd(),10, S)> 0, 5, 0), 0)
MFIIns
if(mfi(20)> 80,5,if(mfi(20)< 20,-5,0))
PDOInS2
dpo(18) - mov(dpo(18), 10, S)
PDOInSB
if(fml("PDOInS2")< 0, if(mov(dpo(18),10,S) < 0, -5, 0), 0)
PDOInSS
if(fml("PDOInS2") > 0, if(mov(dpo(18),10,S) > 0, 5, 0), 0)
ROCInS2
roc(C , 10, $) - mov(roc(C,10,$), 10,S)
ROCInSB
if(fml("ROCInS2") < 0, if(mov(roc(C,10,$),10,S)< 0,-5,0),0)
ROCInSS
if(fml("ROCInS2")> 0, if(mov(roc(C,10,$), 10,S)> 0,5,0),0)
RSIInS
if(rsi(14)> 70,5,if(rsi(14)< 30,-5,0))
STO%dInS
If( Stoch(14 ,3 )> 80 ,5 ,If( Stoch(14 ,3 )<20 ,-5 ,0 ) )
STO%kInS
If( Stoch(14 ,1)> 80 ,5 ,If( Stoch(14 ,1 )<20 ,-5 ,0 ) )
Insynch Indicator
50 + fml("CCIInS") + fml("BOLInSLL") + fml("RSIInS") + fml("sto%kInS") + fml("sto%dInS") +
fml("MFIInS") + fml("EMVInSB") + fml("EMVInSS") + fml("ROCInSS") + fml("ROCInSB") +
ref(fml("PDOInSS"),-10) + ref(fml("PDOInSB"),-10) + fml("MACDInSS") + fml("MACDInSB") |
