Michel,
The Insync formula requires no special translation into 6.5 This formula code came from the Equis site and should work fine as is. One condition though. When setting up the variable calls within a custom formula MSWIN maxs out at 20 per indicator; you must combine one of the 21 formulas/variables listed here so the total is less than 21. I combined the PDOInS2 formula/variable call to keep it <= 20. For a quick copy/paste here is mine with the modification. Watch out for line wraps here. Each line should end with a semicolon. Good luck.
BOLInSLB:= Mov( C ,20 ,S ) - 2 * ( Std( C ,20 ) );
BOLInSUB:= Mov( C ,20 ,S ) + 2 * ( Std( C ,20 ) );
BOLInS2:= ( C - BOLInSLB ) / ( BOLInSUB - BOLInSLB +.0000001);
BOLInSLL:= If( BOLInS2 < .05 ,-5 ,If( BOLInS2 > .95 ,5 ,0 ) );
CCIInS:= If( CCI(14 ) > 100 ,5 ,If( CCI(14 ) < -100 ,-5 ,0 ) );
EMVInS2:= EMV(10 ,S ) - Mov( EMV(10 ,S) ,10 ,S );
EMVInSB:= If( EMVInS2 < 0 ,If( Mov( EMV(10 ,S ) ,10 ,S ) < 0 ,-5 ,0 ) ,0 );
EMVInSS:= If( EMVInS2 > 0 ,If( Mov( EMV(10 ,S ) ,10 ,S ) > 0 ,5 ,0 ) ,0 );
MACDInS2:= MACD() - Mov( MACD() ,10 ,S );
MACDinSB:= If( MACDInS2 < 0 ,If( Mov( MACD() ,10 ,S ) < 0 ,-5 ,0 ) ,0 );
MACDInSS:= If( MACDInS2 > 0 ,If( Mov( MACD() ,10 ,S) > 0 ,5 ,0 ) ,0 );
MFIInS:= If( MFI( 20 ) > 80 ,5 , If( MFI( 20 ) < 20 ,-5 ,0 ) );
{PDOInS2:= DPO( 18 ) - Mov( DPO( 18 ) ,10 ,S );}
PDOInSB:= If( DPO( 18 ) - Mov( DPO( 18 ) ,10 ,S ) < 0 ,If( Mov( DPO( 18 ) ,10 , S) < 0 ,-5 ,0 ) ,0 );
PDOInSS:= If( DPO( 18 ) - Mov( DPO( 18 ) ,10 ,S ) > 0 ,If( Mov( DPO( 18 ) ,10 ,S) > 0 ,5 ,0 ) ,0 );
ROCInS2:= ROC( C ,10 ,$ ) - Mov( ROC( C ,10 ,$ ) ,10 ,S );
ROCInSB:= If( ROCInS2 < 0 ,If( Mov( ROC( C ,10 ,$ ) ,10 ,S ) < 0 ,-5 ,0 ) ,0 );
ROCInSS:= If( ROCInS2 > 0 ,If( Mov( ROC( C ,10 ,$ ) ,10 ,S ) > 0 ,5 ,0 ) ,0 );
RSIInS:= If( RSI(14 ) > 70 ,5 ,If( RSI(14 ) < 30 ,-5 ,0 ) );
STOdInS:= If( Stoch(14 ,3 ) > 80 ,5 ,If( Stoch(14 ,3 ) < 20 ,-5 ,0 ) );
STOkInS:= If( Stoch(14 ,1) > 80 ,5 ,If( Stoch(14 ,1 ) < 20 ,-5 ,0 ) );
{InSync Index}
50 + CCIInS + BOLInSLL + RSIInS + STOkInS + STOdInS + MFIInS + EMVInSB + EMVInSS + ROCInSS + ROCInSB + Ref(PDOInSS ,-10 ) + Ref(PDOInSB ,-10 ) + MACDInSS + MACDInSB |
