5spd - You asked for it, you got it. No warranty. These are what
has worked for me, and I cull them if they're not "pretty".
***************************************************************
//Al's "Under30" Input list
Allgroup
((Max(-1,-175,cl)-Min(-1,-175,cl))/Min(-1,-175,cl))>.9782
//This has empirically yielded a close approximation to
//what is known in TC2000 as a 5% chart, as in "volatile"
Close(0)<30
Close(0)>3
***************************************************************
// Al's Early Scan I, turn up's of early indicators
set MACD=12,26,9
set stochastic=13,8
Input="under30.lst" //Look at stocks <30, over 3, with volatility
Allgroup
MoneyFlowOsc(0)>0 //Money Flow is positive
obv(-2) < MovAvg(-2,18,obv) //OBVcrossed it's 18 day ma in the
obv(0) > MovAvg(0,18,obv) // last three days
rsi(0)>MovAvg(0,9,rsi) //RSI 14 crossed it's 9 day ma during the
rsi(-2)<MovAvg(-2,9,rsi) // last three days
macd(0)>macd(-1) //MACD 12,26,9 was up, net, over 4 days
macd(-1)<macd(-3)
close(0)>close(-1) //Price was up today (last trading day)
**************************************************************
//Al's "W" scan, defined by 2 crosses of macd/macdsignal
//Step one of TWO
set macd=12,26,9
Input="under30.lst"
Allgroup
loop(-5,-30)
min(0,-5,cl)<min(-6,-45,cl)
macd(-1)<macdsignal(-1)
macd(0)>macdsignal(0)
**********************
//"W" Scan, step 2 of 2 finds second leg, or second macd crossover
Input="1W1.lst"
set macd=12,26,9
Loop(0,-4)
Allgroup
macd(-1)<macdsignal(-1)
macd(0)>macdsignal(0)
**************************************************************
//Al's Triple Signal Scan
//Al's OBV, MACD, Stochastics crossing signal within three days
set MACD=12,26,9
set stochastic=13,8
Input="under30.lst"
Allgroup
obv(-4) < MovAvg(-4,18,obv)
obv(0) > MovAvg(0,18,obv)
StochasticPctK(-4) < StochasticPctD(-4)
StochasticPctK(0) > StochasticPctD(-4)
macd(-4) < macdsignal(-4)
macd(0) > macdsignal(0)
moneyflowosc(0)>moneyflowosc(-1)
*********************************************
//Richards' Breakout scan, from Andy Gabor's home page (minor changes)
// geocities.com
Input="under30.lst"
AllGroup
Close( 0 ) > movavg(0,34,cl) // price > avg price past 34d
(Max(-4,-21,hi)/Min(-4,-21,lo))<1.2 // prev month max high no more than 20% over low
High(0) > max(-2,-21,hi) // today's high > last month's
Vol(0) > AvgVol(0,-180) // Volume is greater than the past year's avg vol
AvgVol( 0,-30 ) >= 250 // Av. vol. is at least 25,000 shares last 30 days.
qrs(0)>=80
**************************************************************
//Richard Estes Buy, Buy, Buy modified
Input="under30.lst"
(Close(0)-Close(-4)/Close(-4))>5 //Percent change in last 5 days > 5%
Vol (0)>MovAvg(-1,62,Vol)
Close(0)>Max(-1,-250,cl)*.85
macd(0)>0
stochastic(0)>20
Close(0)>close(-1)
***************************************************************
//Al's 10 Cross 20 scan
// The 10 day moving has crossed over the 20 day moving average, vol up
Input="under30.lst"
Allgroup
MovAvg(0,10,cl) > MovAvg(0,20,cl) // The 10 day MA is above the 20 day ma today
MovAvg(-1,10,cl) < MovAvg(-1,20,cl) // The 10 day ma was below the 20 day ma yesterday
Vol(0)>AvgVol(0,-42)*1.5
Close(0)>Close(-1)
MoneyFlowOsc(0)>0
*****************************************************************
//Al's Price-N-Volume scan
Input="under30.lst" //Scans list of 5 percent stocks volatility, under 30
Allgroup
Vol(0) > AvgVol(0,-65)*2.5 // Volume is gt 2.5 times the 3 month vol moving average
Close(0) / Close(-1) > 1.05 //5% plus, price change from yesterday
******************** END |
